Folgendes Problem:

Ich nutze MS Outlook und möchte meine Kontakte ins Handy überspielen. Funktioniert prinzipiell auch.

Nur ist das Ding zu blöd die Ablage genauso zu machen wie´s Outlook kann: nämlich in der Reihenfolge "Nachname, Vorname" bzw. Firmenname.

Da ich etliche Firmen gespeichert habe und da natürlich konkrete Personen bestenfalls als Notiz (logisch, wer merkt sich sonst schon, welcher Name zu der und der Abteilung dieser und jener Firma gehört) gespeichert sind, ist natürlich KEIN Name in dem speziellen Kontakt gegeben.

Wenn ich also synchronisiere, sind sämtliche Firmeneinträge nur als "Kein Name" im Handy verfügbar. Außerdem sind konkrete Namen in der Reihenfolge "Vorname Nachname" gespeichert, was bei über 200 Einträgen und fürs Geschäftsleben nicht wirklich sinnvoll ist.

Meine Frage also: Wie kann ich der PC Suite beibringen, daß die Kontakte auf die gleiche Art abgelegt werden wie´s im Kontakteordner bei Outlook der Falls ist, nämlich "Nachname Vorname" bzw. "Firmenname".

Bitte sehnlichst um Vorschläge.

Beim K610i (bei andern ähnlich): Menü > Kontakte > Optionen > Erweitert > Sortierfolge > Nach Nachname. Wie man das verdammte "Kein Name" wegbringt, weiss ich auch nicht...

Zitat von mschatzm

Beim K610i (bei andern ähnlich): Menü > Kontakte > Optionen > Erweitert > Sortierfolge > Nach Nachname. Wie man das verdammte "Kein Name" wegbringt, weiss ich auch nicht...

Ja, jetzt habe ich mir selbst geholfen, weil Sony Ericsson offenbar nicht willens oder in der Lage ist, eine saubere Business-Synchronisation hinzukriegen. Hauptsache ihre Telefone können fotografieren, filmen...

Ich habe eine Prozedur im Outlook Visual Basic Editor geschrieben (Extras > Makro > Visual Basic Editor). Der folgende Text kann kopiert werden und dann mit F5 direkt im Editor gestartet werden.
Was macht die Prozedur? Sie kopiert dort, wo es einen Firmennamen aber keinen Namen hat, den Firmennamen ins Namens-Feld (> Ja). Dann synchronisieren. Dann nochmals laufen lassen (> Nein). Damit werden alle Namensfelder, die mit Firmennamen identisch sind, wieder gelöscht.

Sub Sony_Firmen_Synchronisation()
' Kopiert die Firmennamen in Namensfeld, um bei Synchronisation mit Sony Ericsson
' die Anzeige "Kein Name" zu vermeiden.
' Entfernt Namen aus dem Namensfeld, wenn mit Firmennamen identisch.

Dim objApp As Application
Dim objNS As NameSpace
Dim objFolder As MAPIFolder
Dim colContacts As Items
Dim objItem As Object

Set objApp = CreateObject("Outlook.Application")
Set objNS = objApp.GetNamespace("MAPI")
Set objFolder = objNS.PickFolder

Select Case MsgBox("Firmennamen in Namensfeld kopieren [ja]" & vbCrLf & "Firmennamen aus Namensfeld enfernen [nein]", vbQuestion + vbYesNoCancel + vbDefaultButton1, "Firmensynchronisation mit Sony Ericsson")
Case vbYes
If Not objFolder Is Nothing Then
Set colContacts = objFolder.Items
For Each objItem In colContacts
If objItem.Class = olContact Then
With objItem
If .LastName = "" Then ' Nachname muss leer sein
If .CompanyName <> "" Then
.LastName = .CompanyName
.Save
End If
End If
End With
End If
Next
End If
MsgBox "Firmennamen in Namensfeld kopiert. Bereit zur Synchronisation.", vbInformation, "Firmensynchronisation mit Sony Ericsson"
Case vbNo
If Not objFolder Is Nothing Then
Set colContacts = objFolder.Items
For Each objItem In colContacts
If objItem.Class = olContact Then
With objItem
If .CompanyName <> "" Then ' Firmenname darf nicht leer sein
If .CompanyName = .LastName Then
.LastName = ""
.Save
End If
End If
End With
End If
Next
End If
MsgBox "Firmennamen aus Namensfeld gelöscht.", vbInformation, "Firmensynchronisation mit Sony Ericsson"
Case Else
End Select

Set objItem = Nothing
Set colContacts = Nothing
Set objFolder = Nothing
Set objNS = Nothing
Set objApp = Nothing

End Sub

guten tag,

klappt das auch bei outlook 2007?

gruss janko (paul)